linux-qubasis

gen-fspec.awk

(1044B)

 BEGIN {
 	gsub(/\//, "\\/", pkgexclude);
 }
 
 function eval_path(path) {
 	gsub(/\$bindir/,		bindir,		path);
 	gsub(/\$datadir/,		datadir,	path);
 	gsub(/\$mandir/,		mandir,		path);
 	gsub(/\$etcdir/,		etcdir,		path);
 	gsub(/\$libdir/,		libdir,		path);
 	gsub(/\$libexecdir/,	libexecdir,	path);
 	gsub(/\$includedir/,	includedir,	path);
 
 	return path;
 }
 
 function eval_source(source) {
 	gsub(/\$dir/, dir, source);
 	return source;
 }
 
 function exclude(path) {
 	pattern = "^(" pkgexclude ")$"
 	return pkgexclude != "" && path ~ pattern
 }
 
 $1 == "reg" {
 	path = eval_path($3);
 
 	if (exclude(path)) {
 		next
 	}
 
 	print prefix path;
 	print "type=" $1;
 	print "mode=" $2;
 	print "source=" eval_source($4);
 	print "";
 	print "";
 }
 
 $1 == "sym" {
 	path = eval_path($3);
 
 	if (exclude(path)) {
 		next
 	}
 
 	print prefix path;
 	print "type=" $1;
 	print "mode=" $2;
 	print "target=" $4;
 	print "";
 	print "";
 }
 
 $1 == "dir" {
 	path = eval_path($3);
 
 	if (exclude(path)) {
 		next
 	}
 
 	print prefix path;
 	print "type=" $1;
 	print "mode=" $2;
 	print "";
 	print "";
 }